# .tcshrc
#

#
# allgemeine Einstellungen
#

# Aliase definieren
alias h  history 25
alias j  jobs -l
alias la ls -a
alias lf ls -FA
alias ll ls -lA
alias pu pushd
alias po popd
alias rm rm -I

# keine Coredumps
limit coredumpsize 0

# umask auf 022 setzten, so dass neu erstellte Dateien fuer alle lesbar sind
umask 22

# Pfad setzen
set path = (/sbin /bin /usr/sbin /usr/bin /usr/games /usr/local/sbin\
            /usr/local/bin /usr/X11R6/bin $HOME/bin)

# Umgebungsvariablen festlegen
setenv EDITOR    vim
setenv PAGER     less
setenv BLOCKSIZE K
setenv CLICOLOR
setenv CVSROOT   $HOME/Dokumente/cvsroot
setenv HTML_TIDY $HOME/.tidyrc


#
# Einstellungen fuer Login-Shells
#

if ($?prompt) then

  # Tastenbelegungen definieren
  bindkey "^W" backward-delete-word
  bindkey -k up history-search-backward
  bindkey -k down history-search-forward

  # vor Vervollstaendigung history-Einsetzungen vornehemen
  set autoexpand

  # alle Moeglichkeiten der Vervollstaendigung immer anzeigen
  set autolist

  # wenn cd keinen passendes Verzeichnis findet, in $HOME danach suchen
  set cdpath = $HOME

  # Vervollstaendigung sieht Punkte, Striche und Unterstriche als
  # Abkuerzungszeichen an und ignoriert Gross- und Kleinschreibung
  set complete = enhance

  # Auslassungspunkte für nicht angezeigte Directories im Prompt
  set ellipsis

  # doppelte Einträge in der history vermeiden, alte Eintraege durch neuen
  # ersetzen
  set histdup = erase

  # 250 Einraege in der History speichern
  set history = 250

  # bei einem EOF nicht die Shell verlassen
  set ignoreeof

  # bei mehr als 10 Zeilen mit moeglichen Optionen der Vervollstaendigung oder
  # der listing-Funktion fragen, ob alle angezeigt werden sollen
  set listmaxrows = 10

  # Mailboxen, die ueberwacht werden definieren
  set mail = $HOME/Mail/mbox

  # exit-Wert anzeigen, wenn ungleich 0
  set printexitvalue

  # huebsches Prompt setzen
  set prompt = '%n@%m:%B%c03%b%# '

  # besondere Einstellungen fuer xterm
  if ($?TERM) then
    if ($TERM =~ xterm*) then

      # das letzte Kommando im Titel anzeigen
      set esc = `echo x | tr x '\033'`
      set bel = `echo x | tr x '\007'`
      sched +0:00 alias postcmd 'echo -n "${esc}]0;\!#:q${bel}"'

    endif
  endif

  # pushd ohne Argumente wechselt nach $HOME, wie cd
  set pushdtohome

  # bei einem rm * nachfragen
  set rmstar

  # prompt, dass an der rechten Seite angezeigt wird
  set rprompt = '[%P]'

  # 250 Zeilen der history speichern und mit bestehender history-Datei
  # zusammenfuegen, statt zu ueberschreiben
  set savehist = ( 250 merge )

  # bei eingebauten Kommandos und der Vervollstaendigung den Pfad beim Folgen
  # von Symlinks relativ zum Ausgangsverzeichnis konstruieren
  set symlinks = ignore

  # Vervollstaendigungsmodus programmieren, die Erlaeuterungen dazu finden sich
  # auf der manpage von tcsh(1)
  complete {cd,pu,pushd,po,popd} 'p/1/d/'
  complete {man,where,whereis,which,whatis} 'n/*/c/'
  complete chown   'c/*{.,:}/g/' 'p/1/u/:' 'n/-/u/:'
  complete -%*     'c/%/j/'
  complete {fg,bg,stop} 'c/%/j/'
  complete kill    'c/-/S/' 'c/%/j/' 'n/*/`ps -o pid= -x | awk \{print\$1\}`/'
  complete killall 'c/-/S/' 'n/*/`ps -x -c -o command= | awk \{print\$1\}`/'
  complete gunzip  'n/*/f:*.{gz,z,Z,tgz,taz}/'
  complete {bunzip,bunzip2} 'n/*/f:*.{bz2,bz,tbz2,tbz}/'
  complete ftp     'p@1@`awk /machine/\{print\$2\} < $HOME/.netrc`@'
  complete cvs     'p/1/(add admin checkout commit diff export history import \
                   init log rdiff release remove rtag status tag update)/'

endif